checkasm-a.asm 5.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238
  1. ;*****************************************************************************
  2. ;* checkasm-a.asm: assembly check tool
  3. ;*****************************************************************************
  4. ;* Copyright (C) 2008-2018 x264 project
  5. ;*
  6. ;* Authors: Loren Merritt <lorenm@u.washington.edu>
  7. ;* Henrik Gramner <henrik@gramner.com>
  8. ;*
  9. ;* This program is free software; you can redistribute it and/or modify
  10. ;* it under the terms of the GNU General Public License as published by
  11. ;* the Free Software Foundation; either version 2 of the License, or
  12. ;* (at your option) any later version.
  13. ;*
  14. ;* This program is distributed in the hope that it will be useful,
  15. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17. ;* GNU General Public License for more details.
  18. ;*
  19. ;* You should have received a copy of the GNU General Public License
  20. ;* along with this program; if not, write to the Free Software
  21. ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02111, USA.
  22. ;*
  23. ;* This program is also available under a commercial proprietary license.
  24. ;* For more information, contact us at licensing@x264.com.
  25. ;*****************************************************************************
  26. %include "x86inc.asm"
  27. SECTION_RODATA
  28. error_message: db "failed to preserve register", 0
  29. %if ARCH_X86_64
  30. ; just random numbers to reduce the chance of incidental match
  31. ALIGN 16
  32. x6: dq 0x1a1b2550a612b48c,0x79445c159ce79064
  33. x7: dq 0x2eed899d5a28ddcd,0x86b2536fcd8cf636
  34. x8: dq 0xb0856806085e7943,0x3f2bf84fc0fcca4e
  35. x9: dq 0xacbd382dcf5b8de2,0xd229e1f5b281303f
  36. x10: dq 0x71aeaff20b095fd9,0xab63e2e11fa38ed9
  37. x11: dq 0x89b0c0765892729a,0x77d410d5c42c882d
  38. x12: dq 0xc45ea11a955d8dd5,0x24b3c1d2a024048b
  39. x13: dq 0x2e8ec680de14b47c,0xdd7b8919edd42786
  40. x14: dq 0x135ce6888fa02cbf,0x11e53e2b2ac655ef
  41. x15: dq 0x011ff554472a7a10,0x6de8f4c914c334d5
  42. n7: dq 0x21f86d66c8ca00ce
  43. n8: dq 0x75b6ba21077c48ad
  44. n9: dq 0xed56bb2dcb3c7736
  45. n10: dq 0x8bda43d3fd1a7e06
  46. n11: dq 0xb64a9c9e5d318408
  47. n12: dq 0xdf9a54b303f1d3a3
  48. n13: dq 0x4a75479abd64e097
  49. n14: dq 0x249214109d5d1c88
  50. %endif
  51. SECTION .text
  52. cextern_naked puts
  53. ; max number of args used by any x264 asm function.
  54. ; (max_args % 4) must equal 3 for stack alignment
  55. %define max_args 15
  56. %if ARCH_X86_64
  57. ;-----------------------------------------------------------------------------
  58. ; void x264_checkasm_stack_clobber( uint64_t clobber, ... )
  59. ;-----------------------------------------------------------------------------
  60. cglobal checkasm_stack_clobber, 1,2
  61. ; Clobber the stack with junk below the stack pointer
  62. %define argsize (max_args+6)*8
  63. SUB rsp, argsize
  64. mov r1, argsize-8
  65. .loop:
  66. mov [rsp+r1], r0
  67. sub r1, 8
  68. jge .loop
  69. ADD rsp, argsize
  70. RET
  71. %if WIN64
  72. %assign free_regs 7
  73. %else
  74. %assign free_regs 9
  75. %endif
  76. ;-----------------------------------------------------------------------------
  77. ; intptr_t x264_checkasm_call( intptr_t (*func)(), int *ok, ... )
  78. ;-----------------------------------------------------------------------------
  79. INIT_XMM
  80. cglobal checkasm_call, 2,15,16,max_args*8+8
  81. mov r6, r0
  82. mov [rsp+max_args*8], r1
  83. ; All arguments have been pushed on the stack instead of registers in order to
  84. ; test for incorrect assumptions that 32-bit ints are zero-extended to 64-bit.
  85. mov r0, r6mp
  86. mov r1, r7mp
  87. mov r2, r8mp
  88. mov r3, r9mp
  89. %if UNIX64
  90. mov r4, r10mp
  91. mov r5, r11mp
  92. %assign i 6
  93. %rep max_args-6
  94. mov r9, [rsp+stack_offset+(i+1)*8]
  95. mov [rsp+(i-6)*8], r9
  96. %assign i i+1
  97. %endrep
  98. %else
  99. %assign i 4
  100. %rep max_args-4
  101. mov r9, [rsp+stack_offset+(i+7)*8]
  102. mov [rsp+i*8], r9
  103. %assign i i+1
  104. %endrep
  105. %endif
  106. %if WIN64
  107. %assign i 6
  108. %rep 16-6
  109. mova m %+ i, [x %+ i]
  110. %assign i i+1
  111. %endrep
  112. %endif
  113. %assign i 14
  114. %rep 15-free_regs
  115. mov r %+ i, [n %+ i]
  116. %assign i i-1
  117. %endrep
  118. call r6
  119. %assign i 14
  120. %rep 15-free_regs
  121. xor r %+ i, [n %+ i]
  122. or r14, r %+ i
  123. %assign i i-1
  124. %endrep
  125. %if WIN64
  126. %assign i 6
  127. %rep 16-6
  128. pxor m %+ i, [x %+ i]
  129. por m6, m %+ i
  130. %assign i i+1
  131. %endrep
  132. packsswb m6, m6
  133. movq r5, m6
  134. or r14, r5
  135. %endif
  136. jz .ok
  137. mov r9, rax
  138. mov r10, rdx
  139. lea r0, [error_message]
  140. %if FORMAT_ELF
  141. call puts wrt ..plt
  142. %else
  143. call puts
  144. %endif
  145. mov r1, [rsp+max_args*8]
  146. mov dword [r1], 0
  147. mov rdx, r10
  148. mov rax, r9
  149. .ok:
  150. RET
  151. %else
  152. ; just random numbers to reduce the chance of incidental match
  153. %define n3 dword 0x6549315c
  154. %define n4 dword 0xe02f3e23
  155. %define n5 dword 0xb78d0d1d
  156. %define n6 dword 0x33627ba7
  157. ;-----------------------------------------------------------------------------
  158. ; intptr_t x264_checkasm_call( intptr_t (*func)(), int *ok, ... )
  159. ;-----------------------------------------------------------------------------
  160. cglobal checkasm_call, 1,7
  161. mov r3, n3
  162. mov r4, n4
  163. mov r5, n5
  164. mov r6, n6
  165. %rep max_args
  166. push dword [esp+24+max_args*4]
  167. %endrep
  168. call r0
  169. add esp, max_args*4
  170. xor r3, n3
  171. xor r4, n4
  172. xor r5, n5
  173. xor r6, n6
  174. or r3, r4
  175. or r5, r6
  176. or r3, r5
  177. jz .ok
  178. mov r3, eax
  179. mov r4, edx
  180. lea r1, [error_message]
  181. push r1
  182. call puts
  183. add esp, 4
  184. mov r1, r1m
  185. mov dword [r1], 0
  186. mov edx, r4
  187. mov eax, r3
  188. .ok:
  189. REP_RET
  190. %endif ; ARCH_X86_64
  191. ;-----------------------------------------------------------------------------
  192. ; int x264_stack_pagealign( int (*func)(), int align )
  193. ;-----------------------------------------------------------------------------
  194. cglobal stack_pagealign, 2,2
  195. movsxdifnidn r1, r1d
  196. push rbp
  197. mov rbp, rsp
  198. %if WIN64
  199. sub rsp, 32 ; shadow space
  200. %endif
  201. and rsp, ~0xfff
  202. sub rsp, r1
  203. call r0
  204. leave
  205. RET
  206. ; Trigger a warmup of vector units
  207. %macro WARMUP 0
  208. cglobal checkasm_warmup, 0,0
  209. xorps m0, m0
  210. RET
  211. %endmacro
  212. INIT_YMM avx
  213. WARMUP
  214. INIT_ZMM avx512
  215. WARMUP